矿料级配合成计算方法

解此方程组即可求得给定矿料所能组成的最佳配合比。

将以上计算过程编成计算机程序，只要输入已知数据，即可计算并打印出各种矿料的设计配合比和合成级配，如表中所示，源程序见后。该程序的操作过程如下：

1、启动程序 RUN ENTER

2、输入矿料种数N，筛孔种数M。

3、依次输入累计筛余和标准级配中线值，如上例，A（1，2）输入99.4，A（2，1）则输入85.4，B（3）则输入48……。

4、输入完后计算机停止，此时可在键盘上直接改正输错的数据。

5、用GOTO 130启动程序，此时计算机开始计算并打印出结果。

程序如下：

10 clear

12 CLS

15 LOCATE 5,20

20 input "请输入矿料种数N=";n

22 input "请输入筛孔种数M=";m

30 Dim a(m,n),b(m),e(n,n)

40 FOR I=1 TO M

50 FOR J=1 TO N

60 PRINT "A(";I;",";J;")=";

70 INPUT "请输入各种筛孔下每种材料的累计筛余值";A(I,J)

80 NEXT J

90 PRINT "B(";I;")=";

100 INPUT"请输入该种筛孔的标准级配中线值";B(I)

120 NEXT I

125 END

130 FOR I=1 TO N

140 FOR J=I TO N:E(I,J)=0

150 FOR K=1 TO M

160 E(I,J)=E(I,J)+A(K,I)*A(K,J)

170 NEXT K:E(J,I)=E(I,J)

175 NEXT J

177 NEXT I

180 FOR I=1 TO N:E(I,0)=0:E(0,I)=0

182 FOR J=1 TO M

184 E(I,0)=E(I,0)+A(J,I)*B(J)*100

186 NEXT J

187 NEXT I

188 FOR J=1 TO N

190 FOR I=1 TO N-1

192 E(I,J)=E(I,J)-E(N,J)

194 NEXT I:E(N,J)=1

196 E(J,0)=E(J,0)-E(N,0)

200 NEXT J:E(N,0)=100

210 FOR I=1 TO N

220 E(I,I)=E(I,I)+1:NEXT I

230 FOR K=1 TO N

240 P=E(K,K)-1

245 IF P=0 THEN PRINT"ERR":END

250 FOR J=1 TO N

260 E(K,J)=E(K,J)/P:NEXT J

265 FOR I=1 TO N

270 IF I=K THEN 290

275 Q=E(I,K)

277 FOR J=1 TO N

280 E(I,J)=E(I,J)-Q*E(K,J)

285 NEXT J

290 NEXT I

292 NEXT K

295 FOR I=1 TO N

300 E(I,I)=E(I,I)-1

310 NEXT I

600 FOR I=1 TO N

610 FOR J=1 TO N

620 E(0,I)=E(0,I)+E(J,0)*E(I,J)

630 NEXT J

632 NEXT I

640 FOR I=1 TO N

650 PRINT "X";I;"=";E(0,I)+.05

660 NEXT I

670 FOR I=1 TO M:A(I,0)=0

680 FOR J=1 TO N

690 A(I,0)=A(I,0)+A(I,J)*E(0,J)

700 NEXT J

710PRINT "SK";I;" ";A(I,0)/100+.05

720 NEXT I :END